 |
|
BaselScript |
Beschreibung
Arbeit mit Musik
BaselScript arbeitet mit MP3-Dateien.
Musik abspielen:
music mode=play file=name [directory=name]
Standardverzeichnis = #directory_music
Stop Musik:
music mode=stop
Musik weiter spielen:
music mode=resume
Lautstärke einstellen:
music volume=value
Positionieren:
music position=value
Position ablesen:
#position = $music_position()
Dauer ablesen:
#duration = $music_duration()
Beispiel - Musik abspielen
scene=1 name="select and play music" bgcolor=white
section init
file files_list(#file_name,#file_extention, #file_length,#file_date)
timer number =1 interval=100 section=ontimer1
#directory="/APPDIR/music/examples"
// get list of files
directory_list target_file=files_list directory=#directory target_directory="/APPDIR/files"
read file=files_list directory="/APPDIR/files"
#duration =0
#position =0
#volume_max=100
#volume=50
#pause="0"
#titel="Select sound"
call list=list_files
end section
list view list_files
tile=file name= files_list directory="/APPDIR/files"
tile=title text= #titel size=30 color=blue style=bold
tile=item name= #file_name typ=text
tile=button name= #back typ=button text=x section=back
tile=select section=select
end list
section select
#music=#file_name
redraw form
end section
form
tile=property bgcolor=black color=white w=380 h=180 size=30
tile=button name=#button1 x= 10 y=100 text=start section=start
tile=button name=#button2 x=400 y=100 text=pause section=pause
tile=button name=#button3 x= 10 y=290 text=resume section=resume
tile=button name=#button4 x=400 y=290 text=stop section=stop
tile=text name=#sb1t x=10 y=540 w=790 h=80 text=volume color=blue bgcolor=white gravity=center
tile=seekbar name=#sb1 x=10 y=590 w=790 h=200 max=#volume_max position=#volume bgcolor=white color=white section=volume
tile=text name=#sb2t x=10 y=740 w=790 h=80 text=duration bgcolor=white color=blue gravity=center
tile=seekbar name=#sb2 x=10 y =790 w=790 h=200 max=#duration position=#position bgcolor=white color=white section=position
end form
section start
start timer= 1 interval=100
music mode=start file=#music directory= #directory_music_examples
#pause=0
music volume=#volume
#duration=$music_player_duration()
set seekbar_max(#sb2,#duration)
set seekbar_max(#sb1,#volume_max)
set seekbar_position(#sb1,#volume)
end section
section ontimer1
if #pause == 0
#position=$music_player_position()
redraw form
endif
end section
section position
#position=$touch_position()
set seekbar_position(#sb2,#position)
music position=#position
end section
section volume
#volume=$touch_position()
set seekbar_position(#sb1,#volume)
music volume=#volume
end section
section pause
#pause=1
stop timer= 1
music mode= pause
end section
section resume
#pause=0
start timer= 1
music mode= resume
end section
section stop
music mode= stop
stop timer=1
call script= 15_0_play_music
end section
section back
call script=examples
end section
end scene 1